Ginormous

Red5

The open source version of Flash Communication Server named Red5 is progressing very well due to an enthusiastic and hard working team, kudos to Luke Hubbard, he's a machine!

For those not familiar with getting a project from subversion and building it eclipse I've created a quick tutorial in swf format with wink.  This is for red5 but should be equally applicable for any subversion hosted project.

The tutorial assumes you have installed subeclipse and have eclipse 3.1 up and running.

You may view the tutorial here.

icons

I was looking for some inspiration for some cool icons for the adminstration system I'm building for Norfolk Southern Railroad.

I found some good sites but a bit pricey so I'll probably create my own :

Stock Icons
Icon Shock

I found some really professional free ones a few years back but can't find the url...  I want ones done by graphic designers that probably have a 3d feel rather than flat ones that look like window 2 or a programmer created them :)

OpenAMF, Arp and Service Delegate

In my previous post here, I talked about how to catch remoting errors.  It bascially turns out that the onStatus method when a remoting call fails is not called when the .swf is runnig under firefox.

I needed something clean and easy to implement so I extended the ServiceDelegate idea that was in one of the arp demos.

I have my serviceLocator class :

class com.nscorp.app.EMC.service.ServiceLocator extends ServiceLocatorTemplate
{
    private static var inst;        // instance of the Service Locator singleton

    // service constants
    static var authenticationServiceName:String = "AuthenticationService";
    static var administrationServiceName:String = "AdministrationService";
    private static var GATEWAY_KEY="openAMFGateway";
    private static var logger:Logger = Logger.getLogger("com.nscorp.app.EMC.service.ServiceLocator")
   
    // Inherited from template:
    // serviceRegistry (private) - registry of known services
   
    ////////////////////////////////////////////////////////////////////////////
    //
    // Constructor
    //
    ////////////////////////////////////////////////////////////////////////////
    function ServiceLocator ()
    {
        super();
   
        // debug
        NetDebug.initialize();
    }
   
    ////////////////////////////////////////////////////////////////////////////
    //
    // Public Methods
    //
    ////////////////////////////////////////////////////////////////////////////

    ////////////////////////////////////////////////////////////////////////////
    //
    // getInstance()
    //
    // The ServiceLocator is a singleton and this is its accessor method.
    //
    ////////////////////////////////////////////////////////////////////////////
    public static function getInstance ()
    {
        //
        // Return reference to singleton instance
        //
        if ( inst == null )
        {
            // create a single instance of the singleton
            inst = new ServiceLocator();
            return inst;
        }
        else
        {
            // instance already exists, return a reference to it
            return inst;
        }
    }

    ////////////////////////////////////////////////////////////////////////////
    //
    // getService()
    //
    // Override the getService() concrete operation in the superclass,
    // treating it as if it was a hook operation for the purpose of adding
    // some additional run-time validation (to check for serviceType.)
    //
    ////////////////////////////////////////////////////////////////////////////
    public function getService ( serviceName )
    {
        // Get the service instance
        var theService = super.getService ( serviceName );

        //
        // Do some additional validation that is specific to our application.
        //
        if (theService != null)
            return theService;
        else
        {
            trace ("Service Locator Error: Unknown service type requested - "+serviceName);
            trace ("Currently this application can only handle Remoting services.");
        }
    }

    ////////////////////////////////////////////////////////////////////////////
    //
    // Private Methods
    //
    ////////////////////////////////////////////////////////////////////////////

    ////////////////////////////////////////////////////////////////////////////
    //
    // addServices()
    //
    // Override the addServices() primitive operation in the superclass to
    // add the services used by this application.
    //
    ////////////////////////////////////////////////////////////////////////////
    private function addServices ()
    {
        var gatewayURL:String = ApplicationConfigurator.getInstance().getKey(GATEWAY_KEY);
        var authenticationService:Service = new Service ( gatewayURL, null, ServiceLocator.authenticationServiceName, null, null );
        addService ( ServiceLocator.authenticationServiceName, authenticationService);
        var administrationService:Service = new Service(gatewayURL, null, ServiceLocator.administrationServiceName, null, null);
        addService(ServiceLocator.administrationServiceName, administrationService);
    }
}    

I have my ServiceDelegate base class (its an abstract class that should just be inherited from)

class com.nscorp.util.service.ServiceDelegate implements Responder
{
   
    private static var logger:Logger;
   
    private var timeout:Number = 10000;  // 1 second timeout
    private var serviceLocater:ServiceLocator;
    private var service:Service;
    private var responder:Responder;
   
    private var intervalId:Number;
   
   
    public function ServiceDelegate(responder:Responder)
    {
        this.responder = responder;
        logger = Logger.getLogger("com.nscorp.app.EMC.service.AdministrationServiceDelegate");
        logger.debug("ServiceDelegate constructed");
    }
   
   
    public function startTimeout()
    {
        intervalId = setInterval(Delegate.create(this, onTimeout), timeout);   
        SystemController.getInstance().dispatchEvent( {type:StandardEventNames.SERVER_COMMUNICATION_START} );
    }
   
    public function clearTimeout()
    {
        clearInterval(intervalId);   
        SystemController.getInstance().dispatchEvent( {type:StandardEventNames.SERVER_COMMUNICATION_END} );
    }
   
   
   
    public function onResult (resultObj:ResultEvent):Void
    {
        clearTimeout();
        logger.debug("onResult received data");
        this.responder.onResult(resultObj);
    }
   
    public function onFault(faultObj:FaultEvent):Void
    {
        clearTimeout();
        logger.debug("onFault recevied error");
        this.responder.onFault(faultObj);
    }
   
    public function onTimeout():Void
    {
        clearTimeout();
        logger.debug("onTimeout was called");

        SystemController.getInstance().dispatchEvent( {type:StandardEventNames.SERVER_COMMUNICATION_FAILED} );
    }
   
    public function initiateCall(pendingCall:PendingCall)
    {
        startTimeout();
        pendingCall.responder = this;
    }
}

I now inhert from this class my actual service delegate that does the work :

class com.nscorp.app.EMC.service.AdministrationServiceDelegate extends ServiceDelegate
{
    private static var logger:Logger = Logger.getLogger("com.nscorp.app.EMC.service.AdministrationServiceDelegate");
   
   
    public function AdministrationServiceDelegate(responder:Responder)
    {
        super(responder);
        logger.debug("see what super's ontimeout function is " + onTimeout);
        logger.info("AdministrationServiceDelegate constructed");
       
        //service = ServiceLocator.getInstance().getService(ServiceLocator.applicationAliasServiceName);
        service = ServiceLocator.getInstance().getService("AdministrationService");
        service.connection.onStatus = Delegate.create(this, onTimeout);
       
    }
   
   
            

    public function authenticate (authrequest:AuthenticationRequest)   
   {
      
        var pendingCall:PendingCall = service.authenticate(authrequest);
        initiateCall(pendingCall);
    }

  // other methods go here...

} 

and now my command get the id and password, put it in a request object and can just do :

authenticationDelegate = new AdministrationServiceDelegate(this);
authenticationDelegate.changePassword(request);

now if a the gateway is down the ServiceDelegate base class will publish a SERVER_COMMUNICATION_FAILED event, so I can popup a dialog or something to tell the user the server is having issues.

Cheers,
Grant.

How to catch errors when the gateway is down with flash remoting

Using openAMF (and I assume other remoting solutions) when the gateway is up but you send an erroneous request the responder.onFault method is called with the details of the error.  However if the gateway is not up or you have a bad port/ip address the onFault method of the responder is never called.

Jim Cheng on the flashcoders list suggested making a callback to the global onStatus method :

_global.System.onStatus = function(statusObj:Object):Void {

   if (statusObj.code == 'NetConnection.Call.Failed') {
     // The server is down or has become unresponsive.
     // Insert additional code per your application here.
   }

}

This works, but I needed control a individual service call.  I use the ARP framework but it essentialy typical actionscript 2 calls to remoting :

First I created an interface to add a new 'onGateWayDown' method

interface com.nscorp.util.remoting.NSResponder extends  mx.rpc.Responder
{

    // add a failure

    public function onGatewayOffline():Void;

}

and now my responder class for a particular service

class LoginResponder implements NSResponder
{

    public function onGatewayOffline():Void
    {
       trace("The gateway is down !");
     }

     public function onResult (resultObj:ResultEvent):Void 
    {
       trace("got some data);
     }

    public function onFault(faultObj:FaultEvent):Void
    {
        trace("got a fault");
    }
   
}

So now to call my service and handle thing appropriately :

var responder:NSResponder = new LoginResponder();

var authenticationService:Service = new Service ( "http://foo.foo.com?gateway2",  null, "AuthenticationService", null, null );

authenticationService.connection.onStatus = responder;

var pendingCall:PendingCall = service.authentication("someName", "somePassword");

pendingCall.responder = responder;

Now if a fault occurs my onFault method of the LoginResponder is called AND if the gateway is down and the call times-out the onGateWayDown method is called.

This isn't documented too well within macromedias site.